Viquipèdia

Fitxer:Standard symmetric pdfs.svg

Fitxer original ‎(fitxer SVG, nominalment 400 × 300 píxels, mida del fitxer: 390 Ko)

Descripció a Commons

Resum

Descripció
English: Plot of several symmetric unimodal probability densities with unit variance. From highest to lowest peak:
 
red, kurtosis 3, Laplace (D)ouble exponential distribution;
 
orange, kurtosis 2, hyperbolic (S)ecant distribution;
 
green, kurtosis 1.2, (L)ogistic distribution;
 
black, kurtosis 0, (N)ormal distribution;
 
cyan, kurtosis −0.593762…, raised (C)osine distribution;
 
blue, kurtosis −1, (W)igner semicircle distribution;
 
magenta, kurtosis −1.2, (U)niform distribution.
Data
Font MarkSweep
Autor  
Vector:
Permís
(Com reutilitzar aquest fitxer)
Public domain This chart is ineligible for copyright and therefore in the public domain, because it consists entirely of information that is common property and contains no original authorship. For more information, see Commons:Threshold of originality § Charts

العربية | Deutsch | English | español | français | italiano | 日本語 | македонски | română | русский | slovenščina | 中文（简体） | 中文（繁體） | +/−

Jo, el titular dels drets d'autor d'aquest treball, el public sota la següent llicència:
Creative Commons CC-Zero L'ús d'aquest fitxer és regulat sota les condicions de Creative Commons de CC0 1.0 lliurament al domini públic universal.
La persona que ha associat un treball amb aquest document ha dedicat l'obra domini públic, renunciant en tot el món a tots els seus drets de d'autor i a tots els drets legals relacionats que tenia en l'obra, en la mesura permesa per la llei. Podeu copiar, modificar, distribuir i modificar l'obra, fins i tot amb fins comercials, tot sense demanar permís.

Altres versions File:Standard symmetric pdfs logscale.svg
File:Standard symmetric pdfs.png
File:Standard symmetric pdfs logscale.png
SVG genesis
InfoField
 
El codi font d'aquest SVG és vàlid.
 
Aquesta imatge vectorial ha estat creada amb Gnuplot
Codi font
InfoField

Gnuplot code

# Laplace double exponential distribution, kurtosis 3
laplace(x) = exp(-abs(x)*sqrt(2)) * sqrt(0.5)

# sech distribution, kurtosis 2
sech(x) = 2.0 / (exp(x) + exp(-x))
sech_pdf(x) = 0.5 * sech(0.5*pi*x)

# logistic distribution, kurtosis 1.2
slogist = sqrt(3) / pi
logist(x) = exp(-x/slogist) / slogist / (1 + exp(-x/slogist))**2

# normal distribution, kurtosis 0
n(x) = exp(-0.5*x*x) / sqrt(2*pi)

# raised cosine distribution, kurtosis -0.59376
scos = 1.0 / sqrt(1/3.0 - 2/pi**2)
cosine(x) = abs(x)>scos? 0 : (1+cos(x*pi/scos))*0.5/scos

# Wigner semicircle distribution, kurtosis -1
wigner(x) = abs(x)>2? 0 : sqrt(4-x*x)*0.5/pi

# uniform distribution, kurtosis -1.2
uniform(x) = abs(x)>sqrt(3)? 0 : 0.5/sqrt(3)

set samples 6001
set grid

set xrange [-5.4:5.4]
set xtics 1

set key right font ",8" enhanced

set terminal svg size 400,300 enhanced fname 'DejaVu Sans'  fsize 10 butt solid
set output 'Standard symmetric pdfs.svg'

plot \
     laplace(x)  lt 1 lw 2 title "D,  3", \
     sech_pdf(x) lt 8 lw 2 title "S,  2", \
     logist(x)   lt 2 lw 2 title "L,  1.2", \
     n(x)        lt 7 lw 2 title "N,  0", \
     cosine(x)   lt 5 lw 2 title "C, -0.59376", \
     wigner(x)   lt 3 lw 2 title "W, -1", \
     uniform(x)  lt 4 lw 2 title "U, -1.2"

Llegendes

Afegeix una explicació d'una línia del que representa aquest fitxer

Elements representats en aquest fitxer

representa l'entitat

Historial del fitxer

Cliqueu una data/hora per veure el fitxer tal com era aleshores.

Data/horaMiniaturaDimensionsUsuari/aComentari
actual18:15, 26 maig 2020Miniatura per a la versió del 18:15, 26 maig 2020400 × 300 (390 Ko)Andelsmall legend tweak
15:52, 26 maig 2020Miniatura per a la versió del 15:52, 26 maig 2020400 × 300 (390 Ko)Andel== {{int:filedesc}} == {{Information |description=|Description= {{en|1=Plot of several symmetric unimodal probability densities with unit variance. From highest to lowest peak: {{Legend|red|red, kurtosis 3, Laplace (D)ouble exponential distribution;}} {{Legend|orange|orange, kurtosis 2, hyperbolic (S)ecant distribution;}} {{Legend|green|green, kurtosis 1.2, (L)ogistic distribution;}} {{Legend|black|bla...

La pàgina següent utilitza aquest fitxer:

Ús global del fitxer

Utilització d'aquest fitxer en altres wikis:

Metadades

Aquest fitxer conté informació addicional, probablement afegida per la càmera digital o l'escàner utilitzat per a crear-lo o digitalitzar-lo. Si s'ha modificat posteriorment, alguns detalls poden no reflectir les dades reals del fitxer modificat.

Obtingut de «https://ca.wikipedia.org/wiki/Fitxer:Standard_symmetric_pdfs.svg»