Viquipèdia

Fitxer:Lagrangian points equipotential.gif

Lagrangian_points_equipotential.gif ‎(512 × 384 píxels, mida del fitxer: 2 Mo, tipus MIME: image/gif, en bucle, 72 fotogrames, 7,2 s)

Descripció a Commons

Resum

Descripció
English: Animation showing the relationship between the five Lagrangian points (red) of a planet (blue) orbiting a star (yellow), and the gravitational potential in the plane containing the orbit (grey surface with purple contours of equal potential). The potential was computed in POV-Ray using

for q = 0.1 and z = 0.[1]
Font Treball propi
Autor cmglee
Altres versions
Lagrangian points equipotential.png
Lagrangian points equipotential.jpg
Roche potential.stl

POV-Ray source code

Lagrangian_points_equipotential.pov Lagrangian_points_equipotential.ini 
#declare rotation = clock;
// #declare rotation = -28;
#declare bounding_radius = 8;
#declare q = 0.1;
#declare q_plus_1 = q + 1;
#declare q_divide_q_plus_1 = q / q_plus_1;
#declare two_divide_q_plus_1 = 2 / q_plus_1;

union {
 isosurface {
  function {
   y + (pow(x-q_divide_q_plus_1,2) + z*z + two_divide_q_plus_1 * (q / sqrt((x-1)*(x-1)+z*z) + 1 / sqrt(x*x + z*z)))
  } 
  accuracy     0.001
  max_gradient 200 // increase to reduce artifact in funnel
  contained_by {sphere{0,bounding_radius}} open
  pigment {
   gradient <0,1,0>
   color_map {                                               [0.01 color rgb <0.5,0,0.75>][0.02 color rgb 1]
              [0.18 color rgb 1][0.19 color rgb <0.75,0.5,1>][0.21 color rgb <0.75,0.5,1>][0.22 color rgb 1]
              [0.38 color rgb 1][0.39 color rgb <0.75,0.5,1>][0.41 color rgb <0.75,0.5,1>][0.42 color rgb 1]
              [0.58 color rgb 1][0.59 color rgb <0.75,0.5,1>][0.61 color rgb <0.75,0.5,1>][0.62 color rgb 1]
              [0.78 color rgb 1][0.79 color rgb <0.75,0.5,1>][0.81 color rgb <0.75,0.5,1>][0.82 color rgb 1]
              [0.98 color rgb 1][0.99 color rgb <0.75,0.5,1>]                                               }
   scale 0.5
   translate <0,0.03,0>
  }
  scale     <1,0.5,1>
  translate <0,1.42,0>
 }
 union {
  sphere {0,0.2          pigment {rgbt <1,1,0,0.5>}   interior {ior 1} finish {specular 1 roughness 0.1} }
  sphere {<1,0,0>,0.1    pigment {rgbt <0,0.5,1,0.5>} interior {ior 1} finish {specular 1 roughness 0.1} }
  sphere {<q/2,0,0>,0.05 pigment {rgb  <0.5,0,0>} }
  union {
   torus    {1-q/2,0.02 translate <q/2,0,0>}
   cylinder {<-0.95,0,0>,<1.35,0,0>,0.02}
   cylinder {<q/2,0,0>,<0.5,0,0.866>,0.02}
   cylinder {<q/2,0,0>,<0.5,0,-0.866>,0.02}
   pigment  {rgb <0,0.75,0>}
  }
  union {
   union { sphere {0,0.05} cylinder {0,<0,-9,0>,0.02} text {ttf "arlrdbd.ttf" "L1" 0.2, -0.1 scale 0.4 translate <-0.15,0.05,-0.1> rotate <55,rotation,0> no_shadow} translate <0.72,0,0> }
   union { sphere {0,0.05} cylinder {0,<0,-9,0>,0.02} text {ttf "arlrdbd.ttf" "L2" 0.2, -0.1 scale 0.4 translate <-0.15,0.05,-0.1> rotate <55,rotation,0> no_shadow} translate <1.35,0,0> }
   union { sphere {0,0.05} cylinder {0,<0,-9,0>,0.02} text {ttf "arlrdbd.ttf" "L3" 0.2, -0.1 scale 0.4 translate <-0.15,0.05,-0.1> rotate <55,rotation,0> no_shadow} translate <-0.95,0,0> }
   union { sphere {0,0.05} cylinder {0,<0,-9,0>,0.02} text {ttf "arlrdbd.ttf" "L4" 0.2, -0.1 scale 0.4 translate <-0.15,0.05,-0.1> rotate <55,rotation,0> no_shadow} translate <0.5,0,0.866> }
   union { sphere {0,0.05} cylinder {0,<0,-9,0>,0.02} text {ttf "arlrdbd.ttf" "L5" 0.2, -0.1 scale 0.4 translate <-0.15,0.05,-0.1> rotate <55,rotation,0> no_shadow} translate <0.5,0,-0.866> }
   pigment {rgb <1,0,0>}
  }
 }
 translate <-q/2,-0.14,0>
 rotate    <0,-rotation,0>
}
sky_sphere {pigment {rgb 1}}
light_source {<0,1,0>    color rgb 0.5 parallel point_at 0}
light_source {<0,10,-10> color rgb 1   shadowless}
camera {orthographic location <0.05,7.8,-10> look_at <0.05,-0.1,0> angle 13.8}

Antialias=off
Antialias_Threshold=0.01
Antialias_Depth=2

Input_File_Name="Lagrangian_points_equipotential.pov"

Initial_Frame=0
Final_Frame=71
Initial_Clock=0
Final_Clock=360

Cyclic_Animation=on
Pause_when_Done=off
  1. ↑ ZF Seidov, "The Roche Problem: Some Analytics", The Astrophysical Journal, 603:283-284, 2004 March 1

Llicència

Jo, el titular dels drets d'autor d'aquest treball, el public sota les següents llicències:
w:ca:Creative Commons
reconeixement compartir igual
Aquest fitxer està subjecte a la llicència de Creative Commons Reconeixement i Compartir Igual 3.0 No adaptada.
Sou lliure de:
  • compartir – copiar, distribuir i comunicar públicament l'obra
  • adaptar – fer-ne obres derivades
Amb les condicions següents:
  • reconeixement – Heu de donar la informació adequada sobre l'autor, proporcionar un enllaç a la llicència i indicar si s'han realitzat canvis. Podeu fer-ho amb qualsevol mitjà raonable, però de cap manera no suggereixi que l'autor us dóna suport o aprova l'ús que en feu.
  • compartir igual – Si modifiqueu, transformeu, o generareu amb el material, haureu de distribuir les vostres contribucions sota una llicència similar o una de compatible com l'original
GNU head S'autoritza la còpia, la distribució i la modificació d'aquest document sota els termes de la llicència de documentació lliure GNU versió 1.2 o qualsevol altra versió posterior que publiqui la Free Software Foundation; sense seccions invariants, ni textos de portada, ni textos de contraportada. S'inclou una còpia d'aquesta llicència en la secció titulada GNU Free Documentation License.
Podeu seleccionar la llicència que vulgueu.

Llegendes

Afegeix una explicació d'una línia del que representa aquest fitxer

Elements representats en aquest fitxer

representa l'entitat

Historial del fitxer

Cliqueu una data/hora per veure el fitxer tal com era aleshores.

Data/horaMiniaturaDimensionsUsuari/aComentari
actual01:57, 23 oct 2021Miniatura per a la versió del 01:57, 23 oct 2021512 × 384 (2 Mo)CmgleeIncrease resolution and framerate, rotate around barycentre, reframe image and make bodies transparent
12:35, 16 feb 2013Miniatura per a la versió del 12:35, 16 feb 2013256 × 192 (709 Ko)CmgleeUse 6-bit GIFs.
12:06, 16 feb 2013Miniatura per a la versió del 12:06, 16 feb 2013256 × 192 (574 Ko)CmgleeFix shifting background colour.
11:51, 16 feb 2013Miniatura per a la versió del 11:51, 16 feb 2013256 × 192 (574 Ko)CmgleeOrbit around barycentre instead of Sun, darken every fifth contour and double number of frames.
01:41, 16 feb 2013Miniatura per a la versió del 01:41, 16 feb 2013256 × 192 (354 Ko)Cmglee{{Information |Description ={{en|1=Animation showing the relationship between the five Lagrangian points (red) of a planet (blue) orbiting a star (yellow), and the gravitational potential in the plane containing the orbit (grey surface with purple c...

No hi ha pàgines que utilitzin aquest fitxer.

Ús global del fitxer

Utilització d'aquest fitxer en altres wikis:

Metadades

Aquest fitxer conté informació addicional, probablement afegida per la càmera digital o l'escàner utilitzat per a crear-lo o digitalitzar-lo. Si s'ha modificat posteriorment, alguns detalls poden no reflectir les dades reals del fitxer modificat.

Obtingut de «https://ca.wikipedia.org/wiki/Fitxer:Lagrangian_points_equipotential.gif»