Viquipèdia

Viquiprojecte:Cicle de sessions a distància d'Amical Wikimedia 2021/Notes treball sessions WD

< Viquiprojecte:Cicle de sessions a distància d'Amical Wikimedia 2021

Notes treball per la preparació de sessions/tutorials/cursos sobre Wikidata

modifica
Abans de començar
  • Per què és útil fer consultes a Wikidata?
  • Com són les dades estructurades a Wikidata?
  • Vincle entre Viquipèdia i Wikidata (i altres projectes germans)?
  • Connexió de Wikidata amb d'altres bases de dades com OpenStreetMap?
  • Open Linked Data (LOD). Diferències entre Wikidata i altres bases de dades: DBPedia, Freebase/Google KG, YAGO, etc.
Material de treball
  • Utilitat de les consultes PETSCAN a Viquipèdia i Wikidata
  • Per a un curs avançat: PyWikiBot, OSM

Un índex de la sessió sobre SPARQL

modifica 
# fills de Jaume I (ambdós sexes)
SELECT ?persona ?personaLabel WHERE {
  wd:Q212052 wdt:P40 ?persona
  SERVICE wikibase:label { bd:serviceParam wikibase:language "ca". }
}

Prova-ho ! 

# fills de Jaume I (ambdós sexes, versió alternativa)
SELECT ?persona ?personaLabel WHERE {
  ?persona wdt:P22 wd:Q212052.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "ca". }
}

Prova-ho ! 

# filles de Jaume I 
SELECT ?persona ?personaLabel WHERE {
  wd:Q212052 wdt:P40 ?persona.
  ?persona wdt:P21 wd:Q6581072.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "ca". }
}

Prova-ho !

    • Fes servir "modifica visualment" la query anterior per obtenir:
      • Fills (només homes) de Jaume I
      • Fills (ambdós sexes) de Jaume I i Violant d'Hongria
# néts de Jaume I (ambdós sexes)
SELECT ?persona ?personaLabel WHERE {
  wd:Q212052 wdt:P40/wdt:P40 ?persona.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],ca,en". }
}

Prova-ho !

    • Nota: fixeu-vos la conveniència de fer servir més llengües
# fills i néts de Jaume I
SELECT ?persona ?personaLabel WHERE {
  wd:Q212052 wdt:P40/wdt:P40? ?persona.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],ca,en". }
}

Prova-ho ! 

# Jaume I i els seus fills i néts
SELECT DISTINCT ?persona ?personaLabel WHERE {
  wd:Q212052 wdt:P40?/wdt:P40? ?persona.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],ca,en". }
}

Prova-ho !

    • Nota: com que hi ha camins alternatius al mateix element, cal fer servir SELECT DISTINCT per evitar duplicats.
# Hereus potencials de Jaume I (legitimitat a banda)
SELECT DISTINCT ?persona ?personaLabel WHERE {
  ?persona wdt:P22+ wd:Q212052.
  ?persona wdt:P21 wd:Q6581097.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],ca,en". } 
}

Prova-ho ! 

# Hereus potencials de Jaume I amb el pare de cada un
SELECT DISTINCT ?persona ?personaLabel ?pare ?pareLabel  WHERE {
  ?persona wdt:P22+ wd:Q212052.
  ?persona wdt:P21 wd:Q6581097.
  ?persona wdt:P22 ?pare.         
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],ca,en". } 
}

Prova-ho !

    • Nota: Proveu la sortida com a graph.
# Hereus potencials de Jaume I amb el seu pare i la seva mare, si es coneix
SELECT DISTINCT ?persona ?personaLabel ?pare ?pareLabel ?mare ?mareLabel WHERE {
  ?persona wdt:P22+ wd:Q212052.
  ?persona wdt:P21 wd:Q6581097.
  ?persona wdt:P22 ?pare.
  OPTIONAL {?persona wdt:P25 ?mare.}         
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],ca,en". } 
}
#defaultView:Graph

Prova-ho !

Prova-ho !

Prova-ho !

Prova-ho !

  • Articles (schema)
  • Representació del resultat (taules, mapes, grafs).
  • Integració d'SPARQL amb altre eines:
    • SPARQL i Wikishootme. Diferència amb el mapa d'una consulta.
      Obres de Gaudí. Fixeu-vos que només ha calgut introduir ?q wdt:P84 wd:Q25328 al filtre SPARQL del Wikishootme (o sigui, la part important de la consulta). Fer el mateix mapa amb una consulta hagués estat possible però més llarg:
#Obres de Gaudí
SELECT ?obra ?obraLabel ?coord
WHERE {
  ?obra wdt:P84 wd:Q25328.
  ?obra wdt:P625 ?coord.
  SERVICE wikibase:label {bd:serviceParam wikibase:language "ca".}
}
#defaultView:Map

Prova-ho !

    • Si el nombre de punts és petit, és recomanable cliclar l'opció "Worldwide" per que els carregui tots de cop. Si no va carregant, és lent, i no va bé amb àrees grans.
      Vegeu-ne exemples amb Wikishootme (amb i sense Worldwide) i amb una query a la llista de masies del Pla de l'Estany.
    • SPARQL i Petscan.
    • Llistes automàtiques.
    • SPARQL i Commons:
#Autors de fitxers de Commons que representen alguna masia
SELECT ?file ?username
WITH
{
  SELECT ?item 
  WHERE
  {
    SERVICE <https://query.wikidata.org/sparql>
    {
        ?item wdt:P31 wd:Q585956.
     } 
  }
} AS %get_items
WHERE {
  INCLUDE %get_items
  ?file wdt:P180 ?item.
  ?file (p:P170/pq:P4174) ?username.
}
LIMIT 1000

Prova-ho !

Guió introducció sessió Wikidata

modifica
  • Què és Wikidata? (15')
  • Llicències
  • Estructura
  • Suport a les wikis
  • Model de dades (15')
  • Declaració
  • Propietat
  • Valor
  • Edició pràctica a Wikidata (45')
  • Configuració prèvia (usuari amb les preferències per defecte)
  • Exercici pràctic o crear-ne de nou
  • Aplicacions, usos, gadgets (15')

Guió (definitiu?) per la sessió SPARQL

modifica
Objectiu de la sessió
  • Conèixer els conceptes bàsics per recuperar dades WD mitjançant SPARQL
  • Formes de cercar a WD complementàries a SPARQL
  • Consultes bàsiques SPARQL construïdes de forma incremental per comprendre el seu funcionament i saber aplicar-lo en altres casos.
  • Formes de representació dels resultats (mapes, gràfics, imatges,..)
  • Llistes automàtiques
A qui va dirigit
  • Usuaris amb coneixement bàsics de WD (com funciona, estructura de dades: propietats/qualificadors/tipus de valors,..)
  • Habituats a entrar i mantenir continguts
  • Sense o amb molt pocs coneixements d'SPARQL
Guió
Temps Tema Presenta Contingut
3' Benvinguda i presentació dels objectius i que sabran quan acabin AA/PL
5' Què és SPARQL, els standards i la sintaxi dels triples AA (Slides 1-5 de https://w.wiki/3Tke)
Break dubtes
10' Alternatives a una consulta

("què hi enllaça" a Wikidata, "utilitza propietat" al Petscan, etc.)

PL
10' Alternatives a una consulta

(haswbstatement, l'SPARQL dels que volen comptar quants n'hi ha)

AA Provisional: Usuari:Amadalvarez/cerques WD
Break dubtes
Exercici Fet. respostes no integrades a Presentació
30' Casos de consultes progressives. Entendre la sintaxi AA/PL (Slides 6-final de https://w.wiki/3Tke)
10' Formes de representació de resultats PL (Slides 6-final de https://w.wiki/3Tke, variants dels casos)
Break dubtes Fet. respostes no integrades a Presentació
20' Com escriure consultes fàcilment AA/PL (exercici online, per a ser seguit per cadascun dels participants)
Exercici Fet. respostes no integrades a Presentació
Break dubtes
10' Llistes automàtiques com a forma de representació AA https://ca.wikipedia.org/wiki/Ajuda:Llistes_autom%C3%A0tiques
10' Integració amb altres eines (Petscan, Commons, wikishootme, OSM) PL Pendent
Exercicis Petscan i Listeriabot (PL)  ?? PL
Break dubtes
Obtingut de «https://ca.wikipedia.org/w/index.php?title=Viquiprojecte:Cicle_de_sessions_a_distància_d%27Amical_Wikimedia_2021/Notes_treball_sessions_WD&oldid=27729402»